Arch Linux

$ vim hoge.rb
（C-zでvimをサスペンド）
$ ruby hoge.rb
（実行）
$ fg
（vimに戻る）
$ ruby hoge.rb ←これがやりたい
（実行）

# fgとbgを完全に無視したC-p
_up-line-or-history-ignoring() {
    zle up-line-or-history
    case "$BUFFER" in
        fg|bg)
            zle up-line-or-history
            ;;  
    esac
}
zle -N _up-line-or-history-ignoring
bindkey '^P' _up-line-or-history-ignoring

compinit
_comp_options+=(globdots)

zle -N self-insert self-insert-incr
zle -N expand-or-complete-prefix-incr
bindkey '^i' expand-or-complete-prefix-incr
setopt automenu
now_predict=0

function limit-completion
{
	if ((compstate[nmatches] <= 1)); then
		zle -M ""
	elif ((compstate[list_lines] > 6)); then
		compstate[list]=""
		zle -M "too many matches."
	fi
}

function correct-prediction
{
	if ((now_predict == 1)); then
		if [[ "$BUFFER" != "$buffer_prd" ]] || ((CURSOR != cursor_org)); then
			now_predict=0
		fi
	fi
}

function remove-prediction
{
	if ((now_predict == 1)); then
		BUFFER="$buffer_org"
		now_predict=0
	fi
}

function show-prediction
{
	# assert(now_predict == 0)
	if
		((PENDING == 0)) &&
		((CURSOR > 1)) &&
		[[ "$PREBUFFER" == "" ]] &&
		[[ "$BUFFER[CURSOR]" != " " ]]
	then
		cursor_org="$CURSOR"
		buffer_org="$BUFFER"
		comppostfuncs=(limit-completion)
		zle complete-word
		cursor_prd="$CURSOR"
		buffer_prd="$BUFFER"
		if [[ "$buffer_org[1,cursor_org]" == "$buffer_prd[1,cursor_org]" ]]; then
			CURSOR="$cursor_org"
			if [[ "$buffer_org" != "$buffer_prd" ]] || ((cursor_org != cursor_prd)); then
				now_predict=1
			fi
		else
			BUFFER="$buffer_org"
			CURSOR="$cursor_org"
		fi
		echo -n "\e[32m"
	else
		zle -M ""
	fi
}

function preexec
{
	echo -n "\e[39m"
}

function self-insert-incr
{
	correct-prediction
	remove-prediction
	if zle .self-insert; then
		show-prediction
	fi
}

function expand-or-complete-prefix-incr
{
	correct-prediction
	if ((now_predict == 1)); then
		CURSOR="$cursor_prd"
		now_predict=0
		comppostfuncs=(limit-completion)
		zle list-choices
	else
		remove-prediction
		##zle expand-or-complete-prefixを使うとhistoryから補完を選択できる
		zle expand-or-complete-prefix
		##ここで、補間関数をロードするか、若しくは呼び出す処理を書けば_filesがない場合でもTab補完ができるようになる
		##または、独自の補完用テキストファイルを用意しておき、pecoなどと連携する
		#echo "{\"title\":\"test\"},\n{\"body\":\"echo\"}"|peco
	fi
}

zstyle ':completion:*' list-prompt   ''
zstyle ':completion:*' select-prompt ''

# http://d.hatena.ne.jp/mkiken/20130228/1362055601
# https://unix.stackexchange.com/questions/14230/zsh-tab-completion-on-empty-line